Index

@echo off
cls
 
if "%1"=="" goto usage
if not exist "c:\ntbackup\bks\%1.bks" goto usage
 
echo Stopping and Re-starting storage service ...
net stop ntmssvc
net start ntmssvc
sleep 30
 
echo Refreshing RSM ...
rsm.exe refresh /LF"Sony AIT 50 GB SCSI Drive"
 
echo.
echo Waiting for a while ...
sleep 30
 
echo.
echo Setting date and time formats ...
for /f "Tokens=1-4 Delims=/ " %%i in ('date /t') do set dt=%%i-%%l-%%k-%%j
for /f "Tokens=1" %%i in ('time /t') do set tm=%%i
set tm=%tm::=-%
set dtt=%dt%_%tm%
 
echo.
echo Date is %dt%
echo Time is %tm%
 
echo.
echo Running NTBackup using backupset: %1
 
c:\winnt\system32\ntbackup.exe backup "@C:\ntbackup\bks\%1.bks" /n "%computername% %dtt% %1" /d "Daily %dtt% (%1)" /j "Daily %dtt% (%1)" /p "8mm AIT1" /v:yes /r:no /l:s /m normal /rs:no /hc:on /UM
 
goto exit
 
 
:usage
echo Run script with BKS name (in c:\ntbackup\bks\) as first parameter.
echo.
echo eg. c:\ntbackup\ntbackup.cmd Full
echo.
echo Would use c:\ntbackup\bks\Full.bks
echo.
pause.
 
 
:exit
exit

C:\
D:\RMNetwork\
D:\RMUsers\